home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 1 / Cream of the Crop 1.iso / PROGRAM / UCRASM25.ARJ / STRICMPL.ASM < prev    next >
Assembly Source File  |  1991-10-12  |  3KB  |  133 lines
  1. StdGrp        group    StdLib, StdData
  2. ;
  3. StdData        segment    para public 'sldata'
  4.         extrn    $uprtbl:byte
  5. StdData        ends
  6. ;
  7. stdlib        segment    para public 'slcode'
  8.         assume    cs:StdGrp
  9. ;
  10. ;
  11. ; strcmpl- Compares the string pointed at by es:si to the string following
  12. ;       the call instruction.
  13. ;
  14. ; inputs:
  15. ;
  16. ;    es:si-    First string (The string to compare)
  17. ;    cs:rtn-    Second string (The string to compare against)
  18. ;
  19. ;    e.g.,
  20. ;        "if (es:si < cs:rtn) then ..."
  21. ;
  22. ; returns: 
  23. ;
  24. ;    ax- index into strings where they differ (points at the zero byte
  25. ;        if the two strings are equal).
  26. ; 
  27. ;    Condition codes set according to the string comparison.  You should
  28. ;    use the unsigned branches (ja, jb, je, etc.) after calling this
  29. ;    routine.
  30. ;
  31.         public    sl_stricmpl
  32. ;
  33. sl_stricmpl    proc    far
  34.         push    bp
  35.         mov    bp, sp
  36.         push    es
  37.         push    ds
  38.         push    bx
  39.         push    cx
  40.         push    si
  41.         push    di
  42.         mov    ax, es
  43.         mov    ds, ax
  44.         les    di, 2[bp]
  45.         lea    bx, stdgrp:$uprtbl
  46. ;
  47. ; In order to preserve the direction flag across this call, we have to
  48. ; test whether or not it is set here and execute two completely separate
  49. ; pieces of code (so we know which state to exit in.  Unfortunately, we
  50. ; cannot use pushf to preserve this flag since we need to return status
  51. ; info in the other flags.
  52. ;
  53.         pushf
  54.         pop    ax
  55.         test    ah, 4        ;Test direction bit.
  56.         jnz    DirIsSet
  57. ;
  58. ; Compute the length of the string following the CALL instruction:
  59. ;
  60.         cld
  61.         mov    al, 0
  62.         mov    cx, 0ffffh
  63.     repne    scasb
  64.         xchg    di, 2[bp]    ;Save as new return address.
  65. ;
  66.         xor    cx, cx        ;Set char index to zero.
  67. sclp:        lodsb
  68.         xlat    StdGrp:$uprtbl
  69.         mov    ah, al
  70.         mov    al, es:[di]
  71.         xlat    StdGrp:$uprtbl
  72.         cmp    ah, al        
  73.         jne    scNE        ;If strings are <>, quit.
  74.         inc    cx            ;Increment index into strs.
  75.         inc    di        ;Incrment str2 ptr.
  76.         cmp    al, 0        ;Check for end of strings.
  77.         jne    sclp
  78.         pushf
  79.         dec    cx
  80.         popf
  81. ;
  82. scNE:        mov    ax, cx
  83.         pop    di
  84.         pop    si
  85.         pop    cx
  86.         pop    bx
  87.         pop    ds
  88.         pop    es
  89.         pop    bp
  90.         ret            ;Return with direction flag clear.
  91. ;
  92. ;
  93. DirIsSet:    cld
  94.         mov    al, 0
  95.         mov    cx, 0ffffh
  96.     repne    scasb
  97.         xchg    di, 2[bp]    ;Save as new return address.
  98. ;
  99.         xor    cx, cx        ;Set char index to zero.
  100. sclp2:        lodsb
  101.         xlat    StdGrp:$uprtbl
  102.         mov    ah, al
  103.         mov    al, es:[di]
  104.         xlat    StdGrp:$uprtbl
  105.         cmp    ah, al        
  106.         jne    scNE2        ;If strings are <>, quit.
  107.         inc    cx            ;Increment index into strs.
  108.         inc    di        ;Incrment str2 ptr.
  109.         cmp    al, 0        ;Check for end of strings.
  110.         jne    sclp2
  111.         pushf
  112.         dec    cx
  113.         popf
  114. ;
  115. scNE2:        mov    ax, cx
  116.         pop    di
  117.         pop    si
  118.         pop    cx
  119.         pop    bx
  120.         pop    ds
  121.         pop    es
  122.         pop    bp
  123.         std
  124.         ret            ;Return with direction flag set.
  125. ;
  126. ;
  127. ;
  128. sl_stricmpl    endp
  129. ;
  130. ;
  131. stdlib        ends
  132.         end
  133.